软件名称：[B]【日内策略】R-Breaker (源码 贴图 金字塔)[/B]
软件类型：国产软件
运行环境：Win9X/Win2000/WinXP/Win2003/Win7/
软件语言：简体中文
授权方式：免费版
软件大小：2.00 KB
官方主页：Home Page
更新时间：2016-02-26 01:36:51
软件简介:

R-Breaker是个经典的具有长生命周期的日内模型。曾14年排名Future Trust杂志年度前10最赚钱的策略。
类型：日内趋势追踪+反转策略
周期：1分钟、5分钟
适用评台：金字塔

交易规则：
反转:
持多单，当日内最高价超过观察卖出价后，盘中价咯出现回落，且进一步跌破反转卖出价构成的支撑线时，采取反转策略，即在该点位反手做空；
持空单，当日内最低价低于观察买入价后，盘中价咯出现反弹，且进一步超过反转买入价构成的阻力线时，采取反转策略，即在该点位反手做多；
突破:
在空仓的情况下，如果盘中价咯超过突破买入价，则采取趋势策略，即在该点位开仓做多；
在空仓的情况下，如果盘中价咯跌破突破卖出价，则采取趋势策略，即在该点位开仓做空；
代码：
//策略:R-Breaker
//类型:日内
//修订时间:2012.11.1
//Designed By Rogarz

input:ss(1,1,100,10);
手数:=ss;
n:=barslast(date<>ref(date,1));
昨高:=callstock(stklabel,vthigh,6,-1);//昨高
昨低:=callstock(stklabel,vtlow,6,-1);//昨低
昨收:=callstock(stklabel,vtclose,6,-1);//昨收
a:=hhv(h,n+1);
b:=llv(l,n+1);
if N>=1 then begin
今高:=a;//今高
今低:=b;//今低
end
观察卖出价:昨高+0.35*(昨收-昨低);//ssetup
反转卖出价:(1.07/2)*(昨高+昨低)-0.07*昨低;//senter
反转买入价:(1.07/2)*(昨高+昨低)-0.07*昨高;//benter
观察买入价:昨低-0.35*(昨高-昨收);//bsetup
突破买入价:(观察卖出价+0.25*(观察卖出价-观察买入价));//bbreeak
突破卖出价:观察买入价-0.25*(观察卖出价-观察买入价);//sbreak
//条件
空仓做多条件:=c>突破买入价 and holding=0;
空仓做空条件:=c<突破卖出价 and holding=0;
多单反转条件:=holding>0 and 今高>观察卖出价 and c<反转卖出价;
空单反转条件:=holding<0 and 今低<观察买入价 and c>反转买入价;
//交易系统
if time>=092000 and time<151000 then begin
空仓开多:buy(空仓做多条件,手数,market);
空仓开空:buyshort(空仓做空条件,手数,market);
//多单反转:
if 多单反转条件 then begin
  平多:sell(1,手数,market);
  翻空:buyshort(1,手数,market);
  end
//空单反转:
if 空单反转条件 then begin
平空:sellshort(1,手数,market);
翻多:buy(1,手数,market);
end
end
//日内平仓
if time>=151000 then begin
收盘平多:sell(1,手数,market);
收盘平空:sellshort(1,手数,market);
end

这个策略参照国外的经验较适用于股指，在商品上的表现一般，所以此处收盘我以股指为例。

我写这个版本，主要是为了做个可读性强的范例。代码忠于策略本身的思想，没有设置止盈止损，各位可自行添加。
其他考虑不周，或有错的地方。还请各位指教。

根据前一个交易日的收盘价、最高价和最低价数据通过一定方式计算出六个价位，从大到小依次为：突破买入价（Bbreak)、观察卖出价(Ssetup)、反转卖出价(Senter)、反转买入价(Benter)、观察买入价(Bsetup)、突破卖出价(Sbreak)。以此来形成当前交易日盘中交易的触发条件。这里，通过对计算方式的调整。可以调节六个价咯间的距离。

[url=http://www.70822.com/soft/sort013/sort068/down-95246.html]【日内策略】R-Breaker (源码 贴图 金字塔)[/url]