软件名称：[B]倍量，地量，虚拟量，饱和度－－附图[/B]
软件类型：国产软件
运行环境：Win9X/Win2000/WinXP/Win2003/
软件语言：简体中文
授权方式：免费版
软件大小：5.00 KB
官方主页：Home Page
更新时间：2013-02-15 04:23:50
软件简介:

{m1 1 1000 5
 m2 1 1000 10 
 m3 1 1000 30}

VE:VOL,VOLSTICK;
ML5:MA(VE,M1),COLORGREEN;
ML10:MA(VE,M2);
ML35:MA(VE,M3);
绿低量:=13;
蓝低量:=55;
灰低量:=100;
{--------VOL.量能饱和---不懂就去百度-----}
N1:=21;
SAT:=(AMOUNT/C)/(HHV(AMOUNT,20)/HHV(C,20));
饱和:IF(SAT>1,1,SAT)*100,COLOR00AAFF,NODRAW;
中点:=REFDATE(HHV(V,180)*0.5,DATE);
STICKLINE(CURRBARSCOUNT=N1,中点*1.9,中点*1.5,100,1),COLOR00AAFF;
STICKLINE(CURRBARSCOUNT=N1,中点*1.88,中点*1.52,饱和,0),COLOR0077FF;
DRAWTEXT(CURRBARSCOUNT=N1+3,中点*1.8,'饱和度'),COLORYELLOW; 
{=====================================================}
H_L:=0.1*CONST(HHV(VOL,240));
{MAV10:MA(V,10),COLORYELLOW;}
启动5:=MA(V,5),COLORWHITE;
洗盘40:=MA(V,40),COLORBLUE;
异动135:=MA(V,135),COLORMAGENTA; 

虚拟量:=IF(CURRBARSCOUNT=1 AND PERIOD=5,VOL*240/FROMOPEN,DRAWNULL);{模拟量}
STICKLINE(CURRBARSCOUNT=1 AND PERIOD=5,虚拟量,0,1,-1),COLOR00C0C0;
STICKLINE(ISLASTBAR,虚拟量/2,虚拟量/2,36,0),COLORWHITE;

成交量:=VOL,VOLSTICK;
虚倍量:虚拟量/REF(成交量,1),COLORYELLOW,NODRAW;
DRAWNUMBER_FIX(ISLASTBAR,0.995,0,1,虚倍量),COLORWHITE;
成倍量:成交量/REF(成交量,1),COLORWHITE,NODRAW;
换手: VOL*10000/FINANCE(7),NODRAW,COLORRED; {DYNAINFO(37)*100}
换10T:=SUM(换手,10),NODRAW;
倍数:=1.9;
倍量: VOL>=REF(V,1)*倍数 AND (IF(C<O,C>REF(C,1),1)),COLORYELLOW,NODRAW;
倍缩: REF(V,1)>=VOL*倍数,COLORMAGENTA,NODRAW;
平量: RANGE(V/REF(V,1),0.97,1.03) AND BARSCOUNT(V)>=2,COLORWHITE,NODRAW;
低量10: VOL=LLV(VOL,绿低量) AND BARSCOUNT(V)>=绿低量,COLORGREEN,NODRAW;
低量50: VOL=LLV(VOL,蓝低量) AND BARSCOUNT(V)>=蓝低量,COLORBLUE,NODRAW;
地量:VOL=LLV(VOL,灰低量) AND BARSCOUNT(V)>=灰低量,COLORGRAY,NODRAW;

V1:=VOL*0.9;{图标位置}
V2:=VOL*0.8;
STICKLINE(倍量, 0,V1,1,0),COLORYELLOW;
STICKLINE(平量,0,V1,1,0),COLORWHITE;
STICKLINE(低量10,0,V2,1,0),COLORLIGREEN;
STICKLINE(低量50,0,V2,1,0),COLORBLUE;
STICKLINE(地量,0,V2,1,0),COLORGRAY;
STICKLINE(倍缩,0,V*0.45,1,0),COLORMAGENTA;
STICKLINE(C<O AND C>REF(C,1),0,V,0,0),COLORRED;{假阴柱}

真阳或假阴:=C>O OR C>REF(C,1);
收阳:= REF(真阳或假阴,3);
倍量1:=REF(倍量,3); 
高量:=REF(V,3)>=HHV(V,7);
三日不破:= LLV(C,3)>=REF(L,3);
价升:=COUNT(C>=REF(C,1),3)=3;{收盘价逐升}
量缩:=COUNT(V<=REF(V,1),3)=3;
连阳:= COUNT(真阳或假阴,3)=3;
倍量将军柱:= 倍量1 AND 三日不破 AND 收阳;
高量将军柱:= 高量  AND 三日不破 AND 收阳;
将军柱:= 倍量将军柱 OR 高量将军柱;
黄金柱:= 将军柱 AND 价升 AND 量缩 AND 连阳 ;
STICKLINE(黄金柱,0.3*V,0.7*V,1,0),COLORRED; {红柱}
DRAWICON(黄金柱,V*1.5,1);

V100:= V<=LLV(V,100)*1.2 AND V>0 AND BARSCOUNT(V)>=100;
百日地量群:=COUNT(V100,5)>=3;
DRAWTEXT(FILTER(百日地量群,4),V+3*H_L,'地量群'),COLORGRAY;

长阴短柱:=C/REF(C,1)<=0.96 AND V<HHV(V,30)/1.9;
DRAWTEXT(长阴短柱 ,V+1.6*H_L,'！'),COLORLICYAN;

[url=http://www.70822.com/soft/sort013/sort05/down-58723.html]倍量，地量，虚拟量，饱和度－－附图[/url]