现金流量 - 分析家公式网

分析家公式网,提供指标公式,股票软件用户登录 |

首页 ┆ 软件中心 ┆ 备用域名gspt.com ┆ 公式教程 ┆ 软件分类

当前位置：分析家公式网 → 股票公式 → 飞狐公式 → 一键转帖：现金流量

软件名称：[B]现金流量[/B]
软件类型：国产软件
运行环境：Win9X/2000/XP/2003/
软件语言：简体中文
授权方式：解密版
软件大小：3.00 KB
官方主页：Home Page
更新时间：2008-09-19 07:44:06
软件简介:

现金流量》 For Wind

适用于Wind F10资料。

{现金流量--Wind}
INPUT: 项目(1,1,4);
M1:=MA(C,20);
DRAWGBK(C>M1, COLORRGB(90,60,0), COLORRGB(120,40,30),0); {收阳变红}
DRAWGBK(C<M1, COLORRGB(0,110,100), COLORRGB(0,0,0),0); {收阴变绿}
POLYLINE(1,0),COLOR9000EE;
//确定F10种类
F10:=IF(F10FIND('Wind资讯就是',1)>0,2,0);
IF F10<>2 THEN BEGIN
DRAWTEXT(BARPOS=SYSPARAM(2),10,'*** 本公式调用Wind资讯F10 ***'),COLOR96FE33,ALIGN4;
EXIT;
END;
//F10数据查找
QSW:=F10FIND('【6:现金流量】',1000);//起
IF QSW<0 THEN EXIT;//没找到退出

SJT:=F10FIND('财务指标(单位)',QSW+30);//取日期位置1
//HZ:=0;//汇总变量
//查时间
RQZ:=LTRIM(RTRIM(F10TEXT(SJT+22,10)));//时间
最新日期:STRTONUM('1'+STRRIGHT(STRLEFT(RQZ,4),2)+STRRIGHT('0'+NUMTOSTR(STRTONUM(STRMID(RQZ,6,2)),0),2)+STRMID(RQZ,STRFIND(RQZ,'-',6)+1,2)),LINETHICK;

LS:=10;//列取值调整
SJA:=LTRIM(F10TEXT(F10FIND('｜',SJT+LS),0));//取时间行
JYT:=LTRIM(F10TEXT(F10FIND('｜',F10FIND('经营活动现金净流量',SJT+30)+LS),0));//取时间行
JXT:=LTRIM(F10TEXT(F10FIND('｜',F10FIND('现金净流量(万元)',SJT+30)+LS),0));//取时间行
TZT:=LTRIM(F10TEXT(F10FIND('｜',F10FIND('投资活动的现金净流量',SJT+30)+LS),0));//取时间行
CZT:=LTRIM(F10TEXT(F10FIND('｜',F10FIND('筹资活动的现金净流量',SJT+30)+LS),0));//取时间行

//DRAWTEXT(BARPOS=SYSPARAM(2),10,CZT),COLOR96FE33,ALIGN5;//调试用语句

VARIABLE:SJ[4]='str',JYL[4]='str',JXL[4]='str',TZL[4]='str',CZL[4]='str';
FOR j=1 TO 4 DO BEGIN
  SJ[j]:=STRMID(SJA,12*(j-1)+3,10);
  JYL[j]:=LTRIM(STRMID(JYT,12*(j-1)+3,10));
  JXL[j]:=LTRIM(STRMID(JXT,12*(j-1)+3,10));
  TZL[j]:=LTRIM(STRMID(TZT,12*(j-1)+3,10));
  CZL[j]:=LTRIM(STRMID(CZT,12*(j-1)+3,10));
END;
//DRAWTEXT(SYSPARAM(2)+20=BARPOS,15,CZL[1]);//调试用语句

TXTS:=IF(项目=1,'现金净流量',IF(项目=2,'经营现金流',IF(项目=3,'投资现金流','筹资现金流')));
ZBS1:=STRTONUM(IF(项目=1,JXL[1],IF(项目=2,JYL[1],IF(项目=3,TZL[1],CZL[1]))));
ZBS2:=STRTONUM(IF(项目=1,JXL[2],IF(项目=2,JYL[2],IF(项目=3,TZL[2],CZL[2]))));
ZBS3:=STRTONUM(IF(项目=1,JXL[3],IF(项目=2,JYL[3],IF(项目=3,TZL[3],CZL[3]))));
ZBS4:=STRTONUM(IF(项目=1,JXL[4],IF(项目=2,JYL[4],IF(项目=3,TZL[4],CZL[4]))));

最新:ZBS1,COLORFF,PRECISION2,LINETHICK;
上年:ZBS2,COLOREEFF,PRECISION2,LINETHICK;
前年:ZBS3,COLORFFEE00,PRECISION2,LINETHICK;
前三:ZBS4,COLORFF00,PRECISION2,LINETHICK;
本期增减:(最新-上年),COLORAFFF,LINETHICK;

//画柱线
A2:=SYSPARAM(2);AS:=(SYSPARAM(3)-SYSPARAM(2)),LINETHICK;
AG:=IF(AS<20,1,INTPART(AS/IF(AS>120,20,IF(AS>50,18,15))));
STICKLINE(BARPOS=A2+AG,0,ZBS1,AG*4,1),colorFF,LINETHICK2;
STICKLINE(BARPOS=A2+AG*2,0,ZBS2,AG*4,1),colorFFFF,LINETHICK2;
STICKLINE(BARPOS=A2+AG*3,0,ZBS3,AG*4,1),colorFFFF00,LINETHICK2;
STICKLINE(BARPOS=A2+AG*4,0,ZBS4,AG*4,1),colorFF00,LINETHICK2;
DRAWTEXT(BARPOS=SYSPARAM(2),10,TXTS),COLOR96FE33,ALIGN4;

//STICKLINE(SYSPARAM(2)+60=BARPOS,0,STRTONUM(JYL[1]),8,0),COLORFF;
KG:='                                     ';
BT:=F10TEXT(F10FIND('┌',QSW),0);
BT1:=F10TEXT(F10FIND('├',QSW),0);
BW:=F10TEXT(F10FIND('└',QSW),0);
XSS:=KG+BT+' \n'+KG+'｜'+' 财务指标(单位)    '+SJA
+' \n'+KG+'｜'+' 现金净流量(万元) '+JXT
+' \n'+KG+'｜'+' 经营现金净流量    '+JYT
+' \n'+KG+'｜'+' 投资现金净流量    '+TZT
+' \n'+KG+'｜'+' 筹资现金净流量    '+CZT
+' \n'+KG+BW;
DRAWTEXT(SYSPARAM(2)=BARPOS,20,XSS),COLORDD00,ALIGN4;
{
参数精灵
显示项目选择：
1 - 现金净流量  2 - 经营现金流
3 - 投资现金流  4 - 筹资现金流

[url=http://www.70822.com/soft/sort013/sort02/down-355.html]现金流量[/url]