MA交叉线

 

依据均线理论,两均线交叉为均线的重要使用点;如果能预测均线交叉的发展趋势,且能准确判定均线交叉的价咯,使用者一定会得益多多;由本人独自研判的"均线交叉价"方法,已渐趋成熟;本人愿拿出来与广大网友共享;希望得到广大网友的喜爱,支持,高手的斧正,"指标公式"栏的鼓励.

----------------------
{ MA交叉线       标示4条均线交叉价曲线,寻找曲线族形态与股价涨跌间的关系   }
input:n1(5,1,30,1),n2(10,1,30,1),n3(20,1,60,1),n4(30,1,60,1);
收盘价:c,colorffffff,linethick1,PRECIS2;
ma1:=ma(c,n1);ma2:=ma(c,n2);ma3:=ma(c,n3);ma4:=ma(c,n4);

m1m2:(ma2-ma1+ref(c,n1-1)/n1-ref(c,n2-1)/n2)
           *n1*n2/(n2-n1),color0000ff,linethick0,PRECIS2;
m1m3:(ma3-ma1+ref(c,n1-1)/n1-ref(c,n3-1)/n3)
           *n1*n3/(n3-n1),color00ffff,linethick0,PRECIS2;
m2m3:(ma3-ma2+ref(c,n2-1)/n2-ref(c,n3-1)/n3)
           *n2*n3/(n3-n2),colorffff00,linethick0,PRECIS2;
m2m4:(ma4-ma2+ref(c,n2-1)/n2-ref(c,n4-1)/n4)
           *n2*n4/(n4-n2),colorff00ff,linethick0,PRECIS2;
stickline(cross(c,ref(m1m2,1)) ,m1m2*1.10,m1m2*1.5,1,0),color0000ff,linethick2;
stickline(cross(ref(m1m2,1),c) ,m1m2*0.90,m1m2*0.5,1,0),color0000aa,linethick2;
stickline(cross(c,ref(m1m3,1)) ,m1m3*1.10,m1m3*1.5,1,0),color00ffff,linethick2;
stickline(cross(ref(m1m3,1),c) ,m1m3*0.90,m1m3*0.5,1,0),color00aaaa,linethick2;
stickline(cross(c,ref(m2m3,1)) ,m2m3*1.10,m2m3*1.5,1,0),colorffff00,linethick2;
stickline(cross(ref(m2m3,1),c) ,m2m3*0.90,m2m3*0.5,1,0),coloraaaa00,linethick2;
stickline(cross(c,ref(m2m4,1)) ,m2m4*1.10,m2m4*1.5,1,0),colorff00ff,linethick2;
stickline(cross(ref(m2m4,1),c) ,m2m4*0.90,m2m4*0.5,1,0),coloraa00aa,linethick2;


PARTLINE(m1m2 ,ma1>ma2 ,RGB(160,0,0),ma1<=ma2 ,RGB(255,0,0),0),linethick1;
PARTLINE(m1m3 ,ma1>ma3 ,RGB(160,160,0),ma1<=ma3 ,RGB(255,255,0),0),linethick1;
PARTLINE(m2m3 ,ma2>ma3 ,RGB(0,180,180),ma2<=ma3 ,RGB(0,255,255),0),linethick1;
PARTLINE(m2m4 ,ma2>ma4 ,RGB(180,0,180),ma2<=ma4 ,RGB(255,0,255),0),linethick1;
DRAWTEXTREL(300 ,900 ,'指标线含义及用法详见注释"'),color00ffff;

{ 彩色线靠近白线(收盘价)说明两均线交叉条件要求逐渐降低;与0轴很接近,预示即将交叉;
短竖线含义:暗色线上亮竖线 - 两均线金叉;
           亮色线下暗竖线 - 两均线死叉;                                         
亮色线表示两均线处于空头状态,指标线数据为 "明日金叉价";
   大多数时间亮色线处于白线(收盘价)上方,表示 "明日两均线金叉价" 比 "今日收盘价" 要高;
   亮色线处于白线(收盘价)下方,表示 "明日两均线金叉价" 比 "今日收盘价" 要低,预示明日两均线金叉可能性极大;
暗色线表示两均线处于多头状态,指标线数据为"明日死叉价";
   大多数时间暗色线处于0轴下方,表示 "明日两均线死叉价" 比 "今日收盘价" 要低;
   暗色线处于白线(收盘价)上方,表示 "明日两均线死叉价" 比 "今日收盘价" 要高,预示明日两均线死叉可能性极大;

指标线数据含义例举:m1m2表示明日ma1与ma2交叉价;昨日的指标值即为今日的交叉价;
};

-------------------------------------------
{ j均叉减收       标示"均线明日交叉价"(4个)与"今日收盘价" 差的曲线,寻找其与股价涨跌的关系   }
input:n1(5,1,30,1),n2(10,1,30,1),n3(20,1,60,1),n4(30,1,60,1);
     
ma1:=ma(c,n1); ma2:=ma(c,n2); ma3:=ma(c,n3); ma4:=ma(c,n4);
明叉12:=(ma2-ma1+ref(c,n1-1)/n1-ref(c,n2-1)/n2) *n1*n2/(n2-n1);
差12:明叉12-c,color0000ff,linethick0,PRECIS2;
明叉13:=(ma3-ma1+ref(c,n1-1)/n1-ref(c,n3-1)/n3)*n1*n3/(n3-n1);
差13:明叉13-c,color00ffff,linethick0,PRECIS2;
明叉23:=(ma3-ma2+ref(c,n2-1)/n2-ref(c,n3-1)/n3)*n2*n3/(n3-n2);
差23:明叉23-c,colorffff00,linethick0,PRECIS2;
明叉24:=(ma4-ma2+ref(c,n2-1)/n2-ref(c,n4-1)/n4)*n2*n4/(n4-n2);
差24:明叉24-c,colorff00ff,linethick0,PRECIS2;
stickline(cross(ma1,ma2) ,差12,0,1,0),color0000ff,linethick2,LAYER4;
stickline(cross(ma2,ma1) ,差12,0,1,0),color0000aa,linethick2,LAYER4;
stickline(cross(ma1,ma3) ,差13,0,1,0),color00ffff,linethick2,LAYER3;
stickline(cross(ma3,ma1) ,差13,0,1,0),color00aaaa,linethick2,LAYER3;
stickline(cross(ma2,ma3) ,差23,0,1,0),colorffff00,linethick2,LAYER1;
stickline(cross(ma3,ma2) ,差23,0,1,0),coloraaaa00,linethick2,LAYER1;
stickline(cross(ma2,ma4) ,差24,0,1,0),colorff00ff,linethick2,LAYER0;
stickline(cross(ma4,ma2) ,差24,0,1,0),coloraa00aa,linethick2,LAYER0;


PARTLINE(差12 ,ma1>ma2 ,RGB(160,0,0),ma1<=ma2 ,RGB(255,0,0),0),linethick2;
PARTLINE(差13 ,ma1>ma3 ,RGB(160,160,0),ma1<=ma3 ,RGB(255,255,0),0),linethick2;
PARTLINE(差23 ,ma2>ma3 ,RGB(0,180,180),ma2<=ma3 ,RGB(0,255,255),0),linethick2;
PARTLINE(差24 ,ma2>ma4 ,RGB(180,0,180),ma2<=ma4 ,RGB(255,0,255),0),linethick2;
0,coloraaaaaa;
DRAWTEXTREL(300 ,900 ,'指标线含义及用法详见注释"'),color00ffff;
{  彩色线数据表示"明日交叉价"与"今日收盘价"的差;
     含义例举: "差12" 表示 "明日ma1与ma2交叉价" 与 "今日收盘价"的差;   "昨日的收盘价"加"昨日的指标值"即为"今日的交叉价";
彩色线向0靠近说明两均线交叉条件要求逐渐降低;与0轴很接近,预示即将交叉;
短竖线含义:暗色线上亮竖线 - 两均线金叉;
           亮色线下暗竖线 - 两均线死叉;                                         
亮色线表示两均线处于空头状态,指标线数据为"明日金叉价"与"今日收盘价"的差;
   大多数时间亮色线处于0轴上方,数据表示"明日两均线金叉比今日收盘要上涨的最小数值";
   亮色线处于0轴下方,数据表示"明日两均线金叉比今日收盘能下跌的最大数值",预示明日两均线金叉可能性极大;
暗色线表示两均线处于多头状态,指标线数据为"明日金叉价"与"今日收盘价"的差;
   大多数时间暗色线处于0轴下方,数据表示"明日两均线死叉比今日收盘要下跌的最小数值";
   暗色线处于0轴上方,数据表示"明日两均线死叉比今日收盘能上涨的最大数值",预示明日两均线死叉可能性极大;

};